VbScript ile Local Kullanici Yönetimi (Change Local User Password)

Bu yazı Windows Server 2008, Windows Server 2008 R2, Windows Server 2012, Windows Server 2012 R2 ve Windows Server 2016 işletim sistemleri üzerinde kullanılabilecek bilgiler içerir.
Birden fazla sunucuda ya da bilgisayar üzerinde işlem yapmak otomasyon ve scripting gerektiren bir süreçtir. İhtiyaç dahilinde yazmış olduğum scriptle txt uzantılı bir dosyadan sunucu isimleri teker teker okunarak, loop döngüsü içerisinde sunuculara bağlantı kuruluyor ve şifresi değiştirilmek istenilen local kullanıcının sistemde tanımlı olup olmadığı kontrol ediliyor. Eğer local kullanıcı yok ise kullanıcı verilen şifre ile create edilerek administrators lokal grubuna dahil ediliyor, kullanıcı sistemde tanımlı ise şifresi yeni şifreyle değiştiriliyor.

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("D:\computerlist.txt", 1)

myUserName = "myUser"
myPassword = "myNewP@$$w0rd"

Do Until objTextFile.AtEndOfStream

strComputer = objTextFile.ReadLine
err.clear
on error resume next
set objUser = GetObject("WinNT://" & strComputer & "/" & myUserName &", user")

if err.number<>0 then
wscript.echo "User tanımlı degil ya da sunucuya ("&strComputer &") erisilemiyor "
err.clear

strDomain = strComputer
'Creating a User

Set colAccounts = GetObject("WinNT://" & strComputer & "")
Set objUser = colAccounts.Create("user", myUserName)
objUser.SetPassword myPassword
objUser.Description = "Kulanicimin Description Bilgisinde Bu Gözükecek"
objUser.SetInfo

Set objGroup = GetObject("WinNT://" & strComputer & "/Administrators,group")
Set objUser = GetObject("WinNT://" & strComputer & "/" & myUserName &",user")

If (objGroup.IsMember(objUser.AdsPath) = False) Then
objGroup.Add(objUser.ADsPath)

End If' End of If (objGroup.IsMember(objUser.AdsPath) = False) Then

' set password to not expire
intUserFlags = objUser.Get("UserFlags")
objUser.put "Userflags", intUserFlags OR &H10000
objUser.SetInfo

Wscript.echo strComputer & " sunucusunda, " & objUser.Name & "kullanicisi "& objGroup.Name & " grubu altinda olusturulmustur!"


Else
objUser.SetPassword myPassword
objUser.SetInfo


Wscript.echo strComputer & " sunucusunda psm_sos kullanicisinin sifresi degistirilmistir!"
end if
Loop

objTextFile.Close